1 REM PURGE - Remove "Killed" messages from SJBBS data files
2 REM Last change 7/8/80 by Bruce Ratoff
3 REM
5 IF (INP(&H91) AND &H40)=0 THEN 10
6 PRINT "Not allowed remote.":GOTO 310
7 REM
10 PRINT "Purging summary file..."
20 OPEN "R",1,"A:SUMMARY",30
30 FIELD#1,30 AS R1$
40 R1=1
50 OPEN "R",2,"A:$SUMMARY.$$$",30
60 FIELD#2,30 AS R2$
70 R2=1
80 GET#1,R1:IF EOF(1) THEN 150
90 IF VAL(R1$)=0 THEN R1=R1+6:GOTO 80
100 LSET R2$=R1$:PUT#2,R2
103 IF VAL(R1$)>9998 THEN 150
105 PRINT LEFT$(R1$,28)
110 FOR I=1 TO 5
120 R1=R1+1:R2=R2+1:GET#1,R1:LSET R2$=R1$:PUT#2,R2
125 PRINT LEFT$(R2$,28)
130 NEXT I
140 R1=R1+1:R2=R2+1:GOTO 80
150 CLOSE:OPEN "O",1,"SUMMARY.BAK":CLOSE:KILL "SUMMARY.BAK":
     NAME "SUMMARY" AS "SUMMARY.BAK":NAME "$SUMMARY.$$$" AS "SUMMARY"
160 PRINT "Purging message file..."
170 OPEN "R",1,"A:MESSAGES",65:FIELD#1,65 AS R1$
180 OPEN "R",2,"A:$MESSAGS.$$$",65:FIELD#2,65 AS R2$
190 R1=1:R2=1
200 GET#1,R1:IF EOF(1) THEN 300
210 IF VAL(R1$)=0 THEN GET#1,R1+5:R1=R1+VAL(R1$)+6:GOTO 200
220 PRINT LEFT$(R1$,6)
230 LSET R2$=R1$:PUT#2,R2
235 IF VAL(R1$)>9998 THEN 300
240 FOR I=1 TO 5
250 R1=R1+1:R2=R2+1:GET#1,R1:LSET R2$=R1$:PUT#2,R2
255 PRINT LEFT$(R2$,63)
260 NEXT I
270 FOR I=1 TO VAL(R1$):R1=R1+1:R2=R2+1
280 GET#1,R1:LSET R2$=R1$:PUT#2,R2
285 PRINT LEFT$(R2$,63)
290 NEXT I:R1=R1+1:R2=R2+1:GOTO 200
300 CLOSE:OPEN "O",1,"MESSAGES.BAK":CLOSE:KILL "MESSAGES.BAK":
     NAME "MESSAGES" AS "MESSAGES.BAK":NAME "$MESSAGS.$$$" AS "MESSAGES"
310 END